Spiceworld The Movie - Interactive CD-ROM/Spiceworld The Movie: Interactive CD-ROM.iso/pc/elements/spicetwo.dir/scripts_41.ls

Text File | 1997-12-04 | 3.3 KB | 89 lines

on gingerKiss
  global KISSES, PRINTLIST
  if KISSES = VOID then
    set KISSES to 0
  end if
  set kissTimer to 0
  set targetTimer to the ticks
  set currTargetLocs to EMPTY
  set firstRevealCard to 2
  set noOfCardsAcross to 10
  set startTargetNo to 43
  set endTargetNo to 47
  set currTarget to startTargetNo
  set VCrossHairNo to 60
  set HCrossHairNo to 61
  set kissSpriteNo to 50
  set leftPuzzleH to 29
  set topPuzzleV to 74
  set puzzleWidth to 562
  set puzzleHeight to 292
  set pieceWidth to 56
  set pieceHeight to 72
  set the visible of sprite kissSpriteNo to 0
  set noOfPiecesAcross to puzzleWidth / pieceWidth
  set noOfPiecesDown to puzzleHeight / pieceHeight
  set totalPieces to noOfPiecesAcross * noOfPiecesDown
  set the visible of sprite VCrossHairNo to 1
  set the visible of sprite HCrossHairNo to 1
  repeat with x = startTargetNo to endTargetNo
    set piecesAcross to random(noOfPiecesAcross)
    set piecesDown to random(noOfPiecesDown)
    put piecesAcross && piecesDown into line x of currTargetLocs
    set the locH of sprite x to leftPuzzleH + (piecesAcross * pieceWidth)
    set the locV of sprite x to topPuzzleV + (piecesDown * pieceHeight)
  end repeat
  updateStage()
  repeat while the mouseMember = member "kiss mask"
    if (the ticks - targetTimer) > 20 then
      if currTarget = endTargetNo then
        set currTarget to startTargetNo
      else
        set currTarget to currTarget + 1
      end if
      set targetTimer to the ticks
      set piecesAcross to random(noOfPiecesAcross)
      set piecesDown to random(noOfPiecesDown)
      put piecesAcross && piecesDown into line currTarget of currTargetLocs
      set the locH of sprite currTarget to leftPuzzleH + (piecesAcross * pieceWidth)
      set the locV of sprite currTarget to topPuzzleV + (piecesDown * pieceHeight)
      updateStage()
    end if
    if not (kissTimer = 0) then
      if (the ticks - kissTimer) > 10 then
        set the visible of sprite kissSpriteNo to 0
        set kissTimer to 0
      end if
    end if
    set the locV of sprite VCrossHairNo to the mouseV
    set the locH of sprite HCrossHairNo to the mouseH
    updateStage()
    cursor(2)
    if the mouseDown then
      puppetSound("kiss")
      set the locH of sprite kissSpriteNo to the locH of sprite HCrossHairNo
      set the locV of sprite kissSpriteNo to the locV of sprite VCrossHairNo
      set the visible of sprite kissSpriteNo to 1
      updateStage()
      set testV to the locV of sprite kissSpriteNo
      set testH to the locH of sprite kissSpriteNo
      repeat with spriteNo = startTargetNo to endTargetNo
        if (abs(the locV of sprite spriteNo - testV) < 50) and (abs(the locH of sprite spriteNo - testH) < 50) then
          set spriteToHide to ((value(word 2 of line spriteNo of currTargetLocs) - 1) * noOfCardsAcross) + value(word 1 of line spriteNo of currTargetLocs) + (firstRevealCard - 1)
          if the visible of sprite spriteToHide = 1 then
            set the visible of sprite spriteToHide to 0
            set KISSES to KISSES + 1
            if KISSES = totalPieces then
              put "ginger spice print" & RETURN after PRINTLIST
              congratulations()
              returnToMainGame(the frameLabel)
            end if
          end if
          updateStage()
        end if
        set kissTimer to the ticks
      end repeat
    end if
  end repeat
end